Mac Magazin/MacEasy 19/Mac Magazin and MacEasy Magazine CD - Issue 19.iso/Grafik & Text & Film/Quark XTensions/Freeware Xtensions/Scripts folder/Scripts/Guides • Guides to box 1.7-Text

Text File | 1994-04-11 | 4KB | 95 lines

tell application "QuarkXPress®"
    activate

    try
        --this script is meant to run with version 3.3. Version 3.2 will place the guides one point off
        --a slight bug that was corrected in 3.3, aren't you glad the Quark folks are on top of things?
        set QuarkVersion to version as text
        if QuarkVersion is not "3.3" then
            display dialog "This script was designed to run with version 3.3 of QuarkXPress. " & return & ¬
                "Using another version might not produce the proper results." buttons {"Cancel", "Try Anyway"} default button 1
        end if

        --we have to check for an existing document
        if exists document 1 then
            --this activates the routine at the bottom which looks for a single active box
            --if the routine sends back an error this if statement stops
            --if it sends back a true it continues
            if my CheckForSingleBox() is true then

                --give the document to change its measurement sytem to points because
                --we'll be using points to figure the box boundries
                tell document 1
                    set hm to horizontal measure
                    set vm to vertical measure
                    set horizontal measure to points
                    set vertical measure to points

                    --in order to place guides we have to know which page the box is on
                    --an easy way is to give a show command to the box and then show the page
                    --this makes the box appear in the upper left corner of the screen
                    show current box
                    show current page
                    set pagenumber to the index of current page

                    --this get the bounds of the current box in points
                    --bounds are measured from the top and left of the page
                    --A is down from the top of the page to the top left box handle
                    --B is from the left of the page to top left box handle
                    --C  is from the top of the page to the bottom right box handle
                    --D is from the left of the page to the bottom right box handle
                    set boxBounds to bounds of current box as list
                    set a to ((item 1 of boxBounds) as points) as real
                    set b to ((item 2 of boxBounds) as points) as real
                    set C to ((item 3 of boxBounds) as points) as real
                    set D to ((item 4 of boxBounds) as points) as real
                end tell

                --now we tell the page to make the guides. These are page guides
                --not spread guides which go across both pages and pasteboard
                tell page pagenumber of document 1
                    make horizontal guide at beginning with properties {position:a}
                    make vertical guide at beginning with properties {position:b}
                    make horizontal guide at beginning with properties {position:C}
                    make vertical guide at beginning with properties {position:D}
                end tell

                --set the measurement system back to what it was
                tell document 1
                beep
                    set horizontal measure to hm
                    set vertical measure to vm
                end tell
            end if
        else
            beep 2
            display dialog "There is no document currently open!" buttons {"Ooops!"} default button 1 with icon 0
        end if
        --in case of an error a dialog with the error is posted
    on error errtext number errnum
        display dialog errtext buttons {"OK"} default button 1
    end try
end tell


--this routine checks for a single text or picture box that is active
--if no box is active it will error and post the dialog
--if more than one box is active, the active boxes will be thought of by
--XPress as a group and will report a class of group, which will error
--if a line is active (XPress considers lines to be boxes) it will post an error
--it will only return a true if there is a single text or picture box selected
on CheckForSingleBox()
    tell document 1 of application "QuarkXPress®"
        try
            if class of current box is in {picture box, text box} then
                return true
            else
                error
            end if
        on error
            beep
            display dialog "A single text or picture box must be selected to run this script." buttons {"OK"} default button 1
            return false
        end try
    end tell
end CheckForSingleBox